home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
8bitfiles.net/archives
/
archives.tar
/
archives
/
compuserve-file-archive
/
09 Application Software
/
GC1.SDA
/
LIST LOCATIONS
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2019-04-13
|
1KB
|
66 lines
100 REM LIST LOCATIONS
110 REM WRITTEN BY KURT BRANDON
120 REM THE EQUATES IN THE FIRST LINES
130 REM ARE FOR CUSTOMIZING THE
140 REM PROGRAM FOR YOUR OWN PRINTER.
150 REM AS IS, IT RUNS FINE ON A
160 REM STAR NX-1000.
170 :
180 :
190 :
200 DN=PEEK(186):REM DRIVE ADDRESS
210 PN=4:REM PRINTER DEVICE NUMBER
220 TM=5:REM SECONDARY ADDRESS FOR TRANSPARENT MODE
230 Z$=CHR$(0)
240 NC=5:REM NUMBER OF COLUMNS
250 NR=72:REM NUMBER OF ROWS
260 ES$=CHR$(27):REM ESCAPE COMMAND
270 CE$=CHR$(33)+CHR$(5):REM CONDENSED ELITE PRINT (20 CHARACTERS/INCH)
280 TS$=CHR$(68):REM COMMAND TO START SETTING TABS
290 SE$=ES$+TS$+CHR$(32)+CHR$(63)+CHR$(95)+CHR$(127)+Z$
300 REM SE$ SETS TAB STOPS AT COLUMNS 32,63,95 AND 127
310 TA$=CHR$(9):REM TAB COMMAND
320 RS$=CHR$(64):REM RESET COMMAND
325 LS$=ES$+CHR$(65)+CHR$(8):REM SET LINE SPACING TO 1/9 INCH
330 :
340 :
350 :
360 DIMOP$(NR,NC):A=65
370 OPEN1,PN,TM:PRINT#1,ES$CE$LS$
380 OPEN15,DN,15
390 FORI=1TONC
400 FORJ=1TONR
410 IFA=>90ANDRN>MNTHEN440
420 GOSUB570:IFA<=90THENOP$(J,I)=PL$
430 NEXT:NEXT
440 FORX=1TONR
450 FORY=1TONC
460 PRINT#1,OP$(X,Y)TA$;
470 NEXTY
480 PRINT#1,CHR$(10)
490 NEXTX
500 PRINT#1,CHR$(12)
510 FORI=1TONC:FORJ=1TONR:OP$(J,I)="":NEXT:NEXT
520 IFA<90OR(A=90ANDRN<MN)THEN390
530 PRINT#1,ES$RS$:CLOSE1:CLOSE8:CLOSE15:GOTO800
540 :
550 :
560 :
570 IFOP=1THEN600
580 IFOP=0THENOP=1:OPEN8,DN,8,CHR$(A):RN=1
590 GOSUB680:GOSUB690:INPUT#8,MN
600 RN=RN+1:IFRN<=MNTHEN630
610 A=A+1:IFA>90THENRETURN
620 CLOSE8:OP=0:GOTO570
630 GOSUB680:GOSUB690:INPUT#8,PL$,LA$,LO$
640 RETURN
650 :
660 :
670 :
680 RH=INT(RN/256):RL=RN-(256*RH)
690 PRINT#15,"P"+CHR$(96+8)+CHR$(RL)+CHR$(RH)+CHR$(1)
700 INPUT#15,E,E$,AA,B
710 IF E=0ORE=50THENRETURN
720 PRINTE;E$;AA;B:CLOSE1:CLOSE8:CLOSE15:END
800 LOAD"MENU",DN